#!/bin/sh
# @(#) $Id: arp2ethers 1001 2009-07-13 07:32:35Z leres $ (LBL)
#
# Convert arp.dat to ethers format
#
#	- sort on timestamp, newest first
#	- discard entries without simple hostnames
#	- discard all but first occurance of each ethernet address
#	- discard entires with raw ip addresses for simple names
#	- remove ip address and timestamp fields
#	- append "-ip" to hosts with decnet address too
#	- append "-old", "-old1", etc. as necessary
#	- sort
#

sort -k 2 -rn arp.dat | \
    awk 'NF == 4 { print }' |
    awk '
{
	e = $1
	if (seen[e])
		next
	seen[e] = 1
	print
}' | egrep -v '\.[0-9][0-9]*$' | \
     sed -e 's/	.*	/	/' | \
    awk '
BEGIN {
	n = 0
	sdecnet = "aa:0:4:"
	ldecnet = length(sdecnet)
}

{
	++n
	e[n] = $1
	h[n] = $2
	if (sdecnet == substr($1, 1, ldecnet))
		decnet[$2] = 1
}

END {
	for (i = 1; i <= n; ++i) {
		if (decnet[h[i]] && sdecnet != substr(e[i], 1, ldecnet))
			h[i] = h[i] "-ip"
		print e[i] "\t" h[i]
	}
}' | awk '
{
	if (!seen[$2]) {
		seen[$2] = 1
		print
		next
	}
	h = $2 "-old"
	s = h
	for (n = 1; seen[h]; ++n)
		h = s n
	seen[h] = 1
	print $1 "\t" h
	next
}' | sort
